commit f152544a11ed2a8beb6b6c385c604b16df9fb3b6
Author: Pierre Ossman <ossman@cendio.se>
Date:   Wed Dec 8 17:27:07 2010 +0100

    Add a function to find "tools" as opposed to "programs". The difference lies
    in that "tools" depend on the target platform and such have special naming
    when cross-compiling.

diff --git a/Modules/CMakeFindBinUtils.cmake b/Modules/CMakeFindBinUtils.cmake
index 64ec403..3a94c24 100644
--- a/Modules/CMakeFindBinUtils.cmake
+++ b/Modules/CMakeFindBinUtils.cmake
@@ -29,6 +29,8 @@
 # (To distribute this file outside of CMake, substitute the full
 #  License text for the above reference.)
 
+INCLUDE(FindTool)
+
 # if it's the MS C/CXX compiler, search for link
 IF("${CMAKE_CXX_COMPILER_ID}" MATCHES "MSVC" 
    OR "${CMAKE_C_COMPILER_ID}" MATCHES "MSVC"
@@ -43,18 +45,18 @@ ELSE("${CMAKE_CXX_COMPILER_ID}" MATCHES "MSVC"
    OR "${CMAKE_C_COMPILER_ID}" MATCHES "MSVC"
    OR "${CMAKE_GENERATOR}" MATCHES "Visual Studio")
 
-  FIND_PROGRAM(CMAKE_AR NAMES ${_CMAKE_TOOLCHAIN_PREFIX}ar HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
+  FIND_TOOL(CMAKE_AR NAMES ar)
 
-  FIND_PROGRAM(CMAKE_RANLIB NAMES ${_CMAKE_TOOLCHAIN_PREFIX}ranlib HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
+  FIND_TOOL(CMAKE_RANLIB NAMES ranlib)
   IF(NOT CMAKE_RANLIB)
     SET(CMAKE_RANLIB : CACHE INTERNAL "noop for ranlib")
   ENDIF(NOT CMAKE_RANLIB)
 
-  FIND_PROGRAM(CMAKE_STRIP NAMES ${_CMAKE_TOOLCHAIN_PREFIX}strip HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
-  FIND_PROGRAM(CMAKE_LINKER NAMES ${_CMAKE_TOOLCHAIN_PREFIX}ld HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
-  FIND_PROGRAM(CMAKE_NM NAMES ${_CMAKE_TOOLCHAIN_PREFIX}nm HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
-  FIND_PROGRAM(CMAKE_OBJDUMP NAMES ${_CMAKE_TOOLCHAIN_PREFIX}objdump HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
-  FIND_PROGRAM(CMAKE_OBJCOPY NAMES ${_CMAKE_TOOLCHAIN_PREFIX}objcopy HINTS ${_CMAKE_TOOLCHAIN_LOCATION})
+  FIND_TOOL(CMAKE_STRIP NAMES strip)
+  FIND_TOOL(CMAKE_LINKER NAMES ld)
+  FIND_TOOL(CMAKE_NM NAMES nm)
+  FIND_TOOL(CMAKE_OBJDUMP NAMES objdump)
+  FIND_TOOL(CMAKE_OBJCOPY NAMES objcopy)
 
   MARK_AS_ADVANCED(CMAKE_AR CMAKE_RANLIB CMAKE_STRIP CMAKE_LINKER CMAKE_NM CMAKE_OBJDUMP CMAKE_OBJCOPY)
 
diff --git a/Modules/FindPkgConfig.cmake b/Modules/FindPkgConfig.cmake
index c47f583..85c41ff 100644
--- a/Modules/FindPkgConfig.cmake
+++ b/Modules/FindPkgConfig.cmake
@@ -87,7 +87,9 @@
 set(PKG_CONFIG_VERSION 1)
 set(PKG_CONFIG_FOUND   0)
 
-find_program(PKG_CONFIG_EXECUTABLE NAMES pkg-config DOC "pkg-config executable")
+include(FindTool)
+
+find_tool(PKG_CONFIG_EXECUTABLE NAMES pkg-config DOC "pkg-config executable")
 mark_as_advanced(PKG_CONFIG_EXECUTABLE)
 
 if(PKG_CONFIG_EXECUTABLE)
diff --git a/Modules/FindTool.cmake b/Modules/FindTool.cmake
new file mode 100644
index 0000000..c84c0da
--- /dev/null
+++ b/Modules/FindTool.cmake
@@ -0,0 +1,44 @@
+# - Find a build tool.
+#
+#   find_tool(
+#             <VAR>
+#             NAMES name1 [name2 ...]
+#             [DOC "cache documentation string"]
+#             )
+#
+# This is a replacement for find_program() when cross-compliation will 
+# result in the program in being decorated with the machine name (like
+# arm-elf-nm instead of just nm).
+#
+#=============================================================================
+# Copyright 2010 Pierre Ossman <ossman@cendio.se> for Cendio AB
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distributed this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+include(CMakeParseArguments)
+
+function(find_tool _var)
+  set(options )
+  set(oneValueArgs DOC)
+  set(multiValueArgs NAMES)
+
+  cmake_parse_arguments(_find_tool "${options}" "${oneValueArgs}" "${multiValueArgs}"  ${ARGN})
+
+  set(_names )
+  foreach(_name IN LISTS _find_tool_NAMES)
+    list(APPEND _names ${_CMAKE_TOOLCHAIN_PREFIX}${_name})
+  endforeach()
+
+  find_program(${_var}
+               NAMES ${_names}
+               HINTS ${_CMAKE_TOOLCHAIN_LOCATION}
+               DOC ${_find_tool_DOC})
+endfunction()