[cmake-commits] hoffman committed CMakeDependentOption.cmake NONE
1.1.2.1 FindCURL.cmake NONE 1.1.2.1 FindEXPAT.cmake NONE
1.1.2.1 FindXMLRPC.cmake NONE 1.1.2.1
cmake-commits at cmake.org
cmake-commits at cmake.org
Fri Oct 27 16:04:04 EDT 2006
Update of /cvsroot/CMake/CMake/Modules
In directory public:/mounts/ram/cvs-serv25525
Added Files:
Tag: CMake-2-4
CMakeDependentOption.cmake FindCURL.cmake FindEXPAT.cmake
FindXMLRPC.cmake
Log Message:
ENH: move from main tree
--- NEW FILE: FindEXPAT.cmake ---
# - Find expat
# Find the native EXPAT headers and libraries.
#
# EXPAT_INCLUDE_DIRS - where to find expat.h, etc.
# EXPAT_LIBRARIES - List of libraries when using expat.
# EXPAT_FOUND - True if expat found.
# Look for the header file.
FIND_PATH(EXPAT_INCLUDE_DIR NAMES expat.h)
MARK_AS_ADVANCED(EXPAT_INCLUDE_DIR)
# Look for the library.
FIND_LIBRARY(EXPAT_LIBRARY NAMES expat)
MARK_AS_ADVANCED(EXPAT_LIBRARY)
# Copy the results to the output variables.
IF(EXPAT_INCLUDE_DIR AND EXPAT_LIBRARY)
SET(EXPAT_FOUND 1)
SET(EXPAT_LIBRARIES ${EXPAT_LIBRARY})
SET(EXPAT_INCLUDE_DIRS ${EXPAT_INCLUDE_DIR})
ELSE(EXPAT_INCLUDE_DIR AND EXPAT_LIBRARY)
SET(EXPAT_FOUND 0)
SET(EXPAT_LIBRARIES)
SET(EXPAT_INCLUDE_DIRS)
ENDIF(EXPAT_INCLUDE_DIR AND EXPAT_LIBRARY)
# Report the results.
IF(NOT EXPAT_FOUND)
SET(EXPAT_DIR_MESSAGE
"EXPAT was not found. Make sure EXPAT_LIBRARY and EXPAT_INCLUDE_DIR are set.")
IF(NOT EXPAT_FIND_QUIETLY)
MESSAGE(STATUS "${EXPAT_DIR_MESSAGE}")
ELSE(NOT EXPAT_FIND_QUIETLY)
IF(EXPAT_FIND_REQUIRED)
MESSAGE(FATAL_ERROR "${EXPAT_DIR_MESSAGE}")
ENDIF(EXPAT_FIND_REQUIRED)
ENDIF(NOT EXPAT_FIND_QUIETLY)
ENDIF(NOT EXPAT_FOUND)
--- NEW FILE: FindXMLRPC.cmake ---
# - Find xmlrpc
# Find the native XMLRPC headers and libraries.
# XMLRPC_INCLUDE_DIRS - where to find xmlrpc.h, etc.
# XMLRPC_LIBRARIES - List of libraries when using xmlrpc.
# XMLRPC_FOUND - True if xmlrpc found.
# XMLRPC modules may be specified as components for this find module.
# Modules may be listed by running "xmlrpc-c-config". Modules include:
# c++ C++ wrapper code
# libwww-client libwww-based client
# cgi-server CGI-based server
# abyss-server ABYSS-based server
# Typical usage:
# FIND_PACKAGE(XMLRPC REQUIRED libwww-client)
# First find the config script from which to obtain other values.
FIND_PROGRAM(XMLRPC_C_CONFIG NAMES xmlrpc-c-config)
# Check whether we found anything.
IF(XMLRPC_C_CONFIG)
SET(XMLRPC_FOUND 1)
ELSE(XMLRPC_C_CONFIG)
SET(XMLRPC_FOUND 0)
ENDIF(XMLRPC_C_CONFIG)
# Lookup the include directories needed for the components requested.
IF(XMLRPC_FOUND)
# Use the newer EXECUTE_PROCESS command if it is available.
IF(COMMAND EXECUTE_PROCESS)
EXECUTE_PROCESS(
COMMAND ${XMLRPC_C_CONFIG} ${XMLRPC_FIND_COMPONENTS} --cflags
OUTPUT_VARIABLE XMLRPC_C_CONFIG_CFLAGS
OUTPUT_STRIP_TRAILING_WHITESPACE
RESULT_VARIABLE XMLRPC_C_CONFIG_RESULT
)
ELSE(COMMAND EXECUTE_PROCESS)
EXEC_PROGRAM(${XMLRPC_C_CONFIG} ARGS "${XMLRPC_FIND_COMPONENTS} --cflags"
OUTPUT_VARIABLE XMLRPC_C_CONFIG_CFLAGS
RETURN_VALUE XMLRPC_C_CONFIG_RESULT
)
ENDIF(COMMAND EXECUTE_PROCESS)
# Parse the include flags.
IF("${XMLRPC_C_CONFIG_RESULT}" MATCHES "^0$")
# Convert the compile flags to a CMake list.
STRING(REGEX REPLACE " +" ";"
XMLRPC_C_CONFIG_CFLAGS "${XMLRPC_C_CONFIG_CFLAGS}")
# Look for -I options.
SET(XMLRPC_INCLUDE_DIRS)
FOREACH(flag ${XMLRPC_C_CONFIG_CFLAGS})
IF("${flag}" MATCHES "^-I")
STRING(REGEX REPLACE "^-I" "" DIR "${flag}")
FILE(TO_CMAKE_PATH "${DIR}" DIR)
SET(XMLRPC_INCLUDE_DIRS ${XMLRPC_INCLUDE_DIRS} "${DIR}")
ENDIF("${flag}" MATCHES "^-I")
ENDFOREACH(flag)
ELSE("${XMLRPC_C_CONFIG_RESULT}" MATCHES "^0$")
MESSAGE("Error running ${XMLRPC_C_CONFIG}: [${XMLRPC_C_CONFIG_RESULT}]")
SET(XMLRPC_FOUND 0)
ENDIF("${XMLRPC_C_CONFIG_RESULT}" MATCHES "^0$")
ENDIF(XMLRPC_FOUND)
# Lookup the libraries needed for the components requested.
IF(XMLRPC_FOUND)
# Use the newer EXECUTE_PROCESS command if it is available.
IF(COMMAND EXECUTE_PROCESS)
EXECUTE_PROCESS(
COMMAND ${XMLRPC_C_CONFIG} ${XMLRPC_FIND_COMPONENTS} --libs
OUTPUT_VARIABLE XMLRPC_C_CONFIG_LIBS
OUTPUT_STRIP_TRAILING_WHITESPACE
RESULT_VARIABLE XMLRPC_C_CONFIG_RESULT
)
ELSE(COMMAND EXECUTE_PROCESS)
EXEC_PROGRAM(${XMLRPC_C_CONFIG} ARGS "${XMLRPC_FIND_COMPONENTS} --libs"
OUTPUT_VARIABLE XMLRPC_C_CONFIG_LIBS
RETURN_VALUE XMLRPC_C_CONFIG_RESULT
)
ENDIF(COMMAND EXECUTE_PROCESS)
# Parse the library names and directories.
IF("${XMLRPC_C_CONFIG_RESULT}" MATCHES "^0$")
STRING(REGEX REPLACE " +" ";"
XMLRPC_C_CONFIG_LIBS "${XMLRPC_C_CONFIG_LIBS}")
# Look for -L flags for directories and -l flags for library names.
SET(XMLRPC_LIBRARY_DIRS)
SET(XMLRPC_LIBRARY_NAMES)
FOREACH(flag ${XMLRPC_C_CONFIG_LIBS})
IF("${flag}" MATCHES "^-L")
STRING(REGEX REPLACE "^-L" "" DIR "${flag}")
FILE(TO_CMAKE_PATH "${DIR}" DIR)
SET(XMLRPC_LIBRARY_DIRS ${XMLRPC_LIBRARY_DIRS} "${DIR}")
ELSEIF("${flag}" MATCHES "^-l")
STRING(REGEX REPLACE "^-l" "" NAME "${flag}")
SET(XMLRPC_LIBRARY_NAMES ${XMLRPC_LIBRARY_NAMES} "${NAME}")
ENDIF("${flag}" MATCHES "^-L")
ENDFOREACH(flag)
# Search for each library needed using the directories given.
FOREACH(name ${XMLRPC_LIBRARY_NAMES})
# Look for this library.
FIND_LIBRARY(XMLRPC_${name}_LIBRARY
NAMES ${name}
PATHS ${XMLRPC_LIBRARY_DIRS}
NO_DEFAULT_PATH
)
MARK_AS_ADVANCED(XMLRPC_${name}_LIBRARY)
# If any library is not found then the whole package is not found.
IF(NOT XMLRPC_${name}_LIBRARY)
SET(XMLRPC_FOUND 0)
ENDIF(NOT XMLRPC_${name}_LIBRARY)
# Build an ordered list of all the libraries needed.
SET(XMLRPC_LIBRARIES ${XMLRPC_LIBRARIES} "${XMLRPC_${name}_LIBRARY}")
ENDFOREACH(name)
ELSE("${XMLRPC_C_CONFIG_RESULT}" MATCHES "^0$")
MESSAGE("Error running ${XMLRPC_C_CONFIG}: [${XMLRPC_C_CONFIG_RESULT}]")
SET(XMLRPC_FOUND 0)
ENDIF("${XMLRPC_C_CONFIG_RESULT}" MATCHES "^0$")
ENDIF(XMLRPC_FOUND)
# Report the results.
IF(NOT XMLRPC_FOUND)
SET(XMLRPC_DIR_MESSAGE
"XMLRPC was not found. Make sure the entries XMLRPC_* are set.")
IF(NOT XMLRPC_FIND_QUIETLY)
MESSAGE(STATUS "${XMLRPC_DIR_MESSAGE}")
ELSE(NOT XMLRPC_FIND_QUIETLY)
IF(XMLRPC_FIND_REQUIRED)
MESSAGE(FATAL_ERROR "${XMLRPC_DIR_MESSAGE}")
ENDIF(XMLRPC_FIND_REQUIRED)
ENDIF(NOT XMLRPC_FIND_QUIETLY)
ENDIF(NOT XMLRPC_FOUND)
--- NEW FILE: CMakeDependentOption.cmake ---
# - Macro to provide an option dependent on other options.
# This macro presents an option to the user only if a set of other
# conditions are true. When the option is not presented a default
# value is used, but any value set by the user is preserved for when
# the option is presented again.
# Example invocation:
# CMAKE_DEPENDENT_OPTION(USE_FOO "Use Foo" ON
# "USE_BAR;NOT USE_ZOT" OFF)
# If USE_BAR is true and USE_ZOT is false, this provides an option called
# USE_FOO that defaults to ON. Otherwise, it sets USE_FOO to OFF. If
# the status of USE_BAR or USE_ZOT ever changes, any value for the
# USE_FOO option is saved so that when the option is re-enabled it
# retains its old value.
MACRO(CMAKE_DEPENDENT_OPTION option doc default depends force)
IF(${option}_ISSET MATCHES "^${option}_ISSET$")
SET(${option}_AVAILABLE 1)
FOREACH(d ${depends})
STRING(REGEX REPLACE " +" ";" CMAKE_DEPENDENT_OPTION_DEP "${d}")
IF(${CMAKE_DEPENDENT_OPTION_DEP})
ELSE(${CMAKE_DEPENDENT_OPTION_DEP})
SET(${option}_AVAILABLE 0)
ENDIF(${CMAKE_DEPENDENT_OPTION_DEP})
ENDFOREACH(d)
IF(${option}_AVAILABLE)
OPTION(${option} "${doc}" "${default}")
SET(${option} "${${option}}" CACHE BOOL "${doc}" FORCE)
ELSE(${option}_AVAILABLE)
IF(${option} MATCHES "^${option}$")
ELSE(${option} MATCHES "^${option}$")
SET(${option} "${${option}}" CACHE INTERNAL "${doc}")
ENDIF(${option} MATCHES "^${option}$")
SET(${option} ${force})
ENDIF(${option}_AVAILABLE)
ELSE(${option}_ISSET MATCHES "^${option}_ISSET$")
SET(${option} "${${option}_ISSET}")
ENDIF(${option}_ISSET MATCHES "^${option}_ISSET$")
ENDMACRO(CMAKE_DEPENDENT_OPTION)
--- NEW FILE: FindCURL.cmake ---
# - Find curl
# Find the native CURL headers and libraries.
#
# CURL_INCLUDE_DIRS - where to find curl/curl.h, etc.
# CURL_LIBRARIES - List of libraries when using curl.
# CURL_FOUND - True if curl found.
# Look for the header file.
FIND_PATH(CURL_INCLUDE_DIR NAMES curl/curl.h)
MARK_AS_ADVANCED(CURL_INCLUDE_DIR)
# Look for the library.
FIND_LIBRARY(CURL_LIBRARY NAMES curl)
MARK_AS_ADVANCED(CURL_LIBRARY)
# Copy the results to the output variables.
IF(CURL_INCLUDE_DIR AND CURL_LIBRARY)
SET(CURL_FOUND 1)
SET(CURL_LIBRARIES ${CURL_LIBRARY})
SET(CURL_INCLUDE_DIRS ${CURL_INCLUDE_DIR})
ELSE(CURL_INCLUDE_DIR AND CURL_LIBRARY)
SET(CURL_FOUND 0)
SET(CURL_LIBRARIES)
SET(CURL_INCLUDE_DIRS)
ENDIF(CURL_INCLUDE_DIR AND CURL_LIBRARY)
# Report the results.
IF(NOT CURL_FOUND)
SET(CURL_DIR_MESSAGE
"CURL was not found. Make sure CURL_LIBRARY and CURL_INCLUDE_DIR are set.")
IF(NOT CURL_FIND_QUIETLY)
MESSAGE(STATUS "${CURL_DIR_MESSAGE}")
ELSE(NOT CURL_FIND_QUIETLY)
IF(CURL_FIND_REQUIRED)
MESSAGE(FATAL_ERROR "${CURL_DIR_MESSAGE}")
ENDIF(CURL_FIND_REQUIRED)
ENDIF(NOT CURL_FIND_QUIETLY)
ENDIF(NOT CURL_FOUND)
More information about the Cmake-commits
mailing list